Unreal を Apple の Mac エコシステムと統合する

• Mac App Store で販売することによって、ゲームに特化したデジタル ストアに立ち寄らない人たちに対しても、組織だってアピールできる。
• iCloud または Game Center を使用してリーダーボードやクラウド保存などを扱うと、サードパーティーのインフラストラクチャをアプリに統合することなく、無料で信頼できるファーストパーティー製のサービスに依拠することができる。
• Apple Arcade には Game Center と iCloud が必須であるため、異なるデバイスからクラウド保存に必ずアクセスできるようになる。

Apple Developer ポータルで Mac 向けアプリをセットアップする

1. Apple Developer Program に参加する。 (年間 99ドルの登録料が必要です。)
2. Certificates, Identifiers & Profiles のページの Identifiers セクションから App Identifier を作成する。
   1. アプリのための Bundle ID を作成する。例: “com.mycompany.mygame”
   2. iCloud および Game Center、その他必要な機能を有効にする。
   3. 注意: すでに iOS 版のゲームのために有効な App ID を作っている場合は、Mac の Identifier を自動生成させることができます。その場合は、iOS App の Identifier の設定項目から Mac の capability を選択します。
3. Certificates, Identifiers & Profiles のページの Certificates セクションでアカウントの Certificate (証明書) を作成します。
   1. Certificate Signing Request (証明書署名要求) をローカルで作成する。
   2. これを使用して、次のための Certificate を作成およびダウンロードする。
      1. Mac Development
      2. Mac App Distribution
      3. Mac Installer Distribution
4. Certificates, Identifiers & Profiles のページの Devices セクションで、所有しているテスト用または開発用の Mac を追加する。
   1. System Report 機能によって Mac の UDID を見つけることができる。
5. (任意) Certificates, Identifiers & Profiles のページの Identifiers セクションで iCloud コンテナを作成する。
   1. App Identifier を編集するとともに、iCloud 機能の横にあるボタンを使ってコンテナを割り当てる。
6. 関連する Provisioning Profile を作成およびダウンロードする。
   1. Mac Development Provisioning Profile を作成する。
      1. 必ず、新たに作成した App Identifier および Certificate、Device を選択する。
   2. Mac App Store のための Provisioning Profile を作成する。
7. 新たな macOS app を App Store Connect で作成し、新たな Bundle ID を選択する。
8. Unreal でプロジェクトを開く。[Project Settings](プロジェクト設定) で、[Platforms](プラットフォーム) > [iOS] を開き、Bundle Identifier に新しい Bundle ID を設定する。

Mac 向けゲームを Apple API と統合する

Objective-C++ とはどのような言語か？

Mac で Game Center をサポートする

1. プレイヤーを認証する
2. 認証されたプレーヤーを使って、アチーブメントやリーダーボードなどを呼び出す。

 if (Target.Platform == UnrealTargetPlatform.Mac) {
            PublicFrameworks.AddRange(new string[]{"GameKit"});
        }

#include <GameKit/GameKit.h>

void UMyBlueprintFunctionLibrary::GameCenterSignIn() {
#if WITH_EDITOR
    // エディタでは実行しない。
#elif PLATFORM_MAC
    // GameCenter に非同期にログインする。コードの中で、
    // デリゲートまたは UBlueprintAsyncActionBase を使って書くことによって、
    // ログインに時間がかかる場合に対処できるようにすることをおすすめします。
    dispatch_async(dispatch_get_main_queue(), ^{
        [[GKLocalPlayer localPlayer]
         setAuthenticateHandler:^(NSViewController *_Nonnull viewController, NSError *error) {
             if ([[GKLocalPlayer localPlayer] isAuthenticated])
             {
                 // 成功
                 return;
             }
             if (error)
             {
                 // 失敗
             }
             else if (viewController)
             {
                 // ログインを表示
                 GKDialogController *presenter = [GKDialogController sharedDialogController];
                 presenter.parentWindow = [NSApp keyWindow];
                 [presenter presentViewController:(NSViewController * _Nonnull) viewController];
             }
         }];
    });
#endif
}

#include <GameKit/GameKit.h>

void UMyBlueprintFunctionLibrary::WriteAchievement(FString ID, float Percent)
{
#if PLATFORM_MAC
    if (![[GKLocalPlayer localPlayer] isAuthenticated])
        return;
    
    // FString を NSString に変換する。
    NSString *nsID = [NSString stringWithUTF8String:TCHAR_TO_ANSI(*ID)];
    
    GKAchievement *achievement = [[GKAchievement alloc] initWithIdentifier:nsID];
    achievement.percentComplete = Percent;
    achievement.showsCompletionBanner = YES;
    [GKAchievement reportAchievements:@[ achievement ]withCompletionHandler:^(NSError *error) {
        if (error != nil)
        {
            NSLog(@"%@", [error localizedDescription]);
        }
    }];
#endif
}

#include <GameKit/GameKit.h>

void UMyBlueprintFunctionLibrary::WriteScoreToLeaderboard(FString LeaderboardID, int Integer) {
#if PLATFORM_MAC
    if (![[GKLocalPlayer localPlayer] isAuthenticated])
        return;
    
    // FString を NSString に変換する。
    NSString *nsID = [NSString stringWithUTF8String:TCHAR_TO_ANSI(*LeaderboardID)];
    
    GKScore *score = [[GKScore alloc] initWithLeaderboardIdentifier:nsID];
    score.value = Integer;
    
    [GKScore reportScores:@[score] withCompletionHandler:^(NSError *error) {
        if (error != nil)
        {
            NSLog(@"%@", [error localizedDescription]);
        }
    }];
#endif
}

クラウド保存のために iCloud を利用する

1. 保存オブジェクトの各フィールドを iCloud における独自のフィールドとして扱う (たとえば、プレーヤーのレベル フィールドは「レベル」という整数、キャラクターの名前は「名前」という文字列など）。
2. 保存オブジェクトをバイナリデータにシリアル化し、保存データ全体を1つのバイナリグロブとして単一の iCloud フィールドにアップロードする。

if (Target.Platform == UnrealTargetPlatform.Mac) {
            PublicWeakFrameworks.Add("CloudKit");
        }

#include <CloudKit/CloudKit.h>
#include "GameFramework/SaveGame.h"
#include "Kismet/GameplayStatics.h"
#include "Serialization/MemoryReader.h"
#include "Serialization/MemoryWriter.h"
#include "Serialization/ObjectAndNameAsStringProxyArchive.h"


void UMyBlueprintFunctionLibrary::WriteSaveToCloud(USaveGame* MySave) {
    TArray<uint8> ObjectBytes;
    FMemoryWriter MemoryWriter(ObjectBytes, true);
    FObjectAndNameAsStringProxyArchive Ar(MemoryWriter, false);
    MySave->Serialize(Ar);
    
    CKContainer *defaultContainer =
        [CKContainer containerWithIdentifier:@"iCloud.unrealtutorial.mygame"];
    if (defaultContainer == nil)
    {
        // 初期化失敗
        return;
    }
    else
    {
        CKDatabase *DB = [defaultContainer privateCloudDatabase];
        CKRecordID *recordId = [[[CKRecordID alloc] initWithRecordName:@"save_game_id"] autorelease];
        // RecordType "SaveGame" は Apple のオンライン iCloud ダッシュボードで設定される。
        CKRecord *record = [[CKRecord alloc] initWithRecordType:@"SaveGame" recordID:recordId];
        // Unreal のデータ配列を NSData バイトに変換する。
        NSData *data = [NSData dataWithBytes:ObjectBytes.GetData() length:ObjectBytes.Num()];
        record[@"SaveData"] = data;
        
        // CKModifyRecordsOperation を使って、既存のレコードを更新できるようにする。
        CKModifyRecordsOperation *modifyRecords =
        [[CKModifyRecordsOperation alloc] initWithRecordsToSave:@[ record ]
                                              recordIDsToDelete:nil];
        modifyRecords.savePolicy = CKRecordSaveAllKeys;
        modifyRecords.qualityOfService = NSQualityOfServiceUserInitiated;
        modifyRecords.perRecordCompletionBlock = ^(CKRecord *results, NSError *error) {
            if (error != nil)
            {
                NSLog(@"icloud save error: %@", error);
            }
            else
            {
                NSLog(@"icloud save success: %@", results);
            }
        };
        [DB addOperation:modifyRecords];
    }
}

#include <CloudKit/CloudKit.h>
#include "GameFramework/SaveGame.h"
#include "Kismet/GameplayStatics.h"
#include "Serialization/MemoryReader.h"
#include "Serialization/MemoryWriter.h"
#include "Serialization/ObjectAndNameAsStringProxyArchive.h"

UCustomSaveGame* UMyBlueprintFunctionLibrary::LoadFromCloud() {
    CKContainer *defaultContainer =
    [CKContainer containerWithIdentifier:@"iCloud.unrealtutorial.mygame"];
    if (defaultContainer == nil)
    {
        return nullptr;
    }
    else
    {
        NSPredicate *predicate = [NSPredicate predicateWithFormat:@"TRUEPREDICATE"];
        CKDatabase *publicDatabase = [defaultContainer privateCloudDatabase];
        CKRecordID *recordID = [[CKRecordID alloc] initWithRecordName:@"save_game_id"];
        
        __block NSData *data = nil;
        // このブロックの結果を保持して、予期せずに GC されないようにする。
        __block CKRecord *holdResults;
        
        // 注意：これは、デリゲートやセマフォ、その他の手段を使用して同期する必要があります。
        [publicDatabase
         fetchRecordWithID:recordID
         completionHandler:^(CKRecord *results, NSError *error) {
             holdResults = results;
             if (error != nil)
             {
                 NSLog(@"icloud load error: %@", error);
             }
             else
             {
                 NSLog(@"icloud load success: %@", results);
                 data = [[NSData alloc] initWithData:(NSData *) results[@"SaveData"]];
             }
         }];
        
        // Sleep と同期させないこと。これは例のためだけに置いている。
        usleep(3000000); // 非同期ロードを待機する。
                
        // データを保存オブジェクトに読み込む。
        TArray<uint8> ObjectBytes;
        ObjectBytes.AddUninitialized(data.length);
        FMemory::Memcpy(ObjectBytes.GetData(), data.bytes, data.length * sizeof(uint8));
        FMemoryReader MemoryReader(ObjectBytes, true);
        FObjectAndNameAsStringProxyArchive Ar(MemoryReader, true);
        UCustomSaveGame *LoadedSave = Cast<UCustomSaveGame>(                                                                UGameplayStatics::CreateSaveGameObject(UCustomSaveGame::StaticClass()));

        LoadedSave->Serialize(Ar);
        return LoadedSave;
    }
}

• ゲームはどれくらいの頻度で保存されるか？どのくらいの頻度でロードするか？保存とロードのたびにクラウドと通信する必要があるか、それともその一部でのみ通信する必要があるのか？
• 複数のデバイスが同じ iCloud レコードへの書き込みと読み取りを行うという機能をサポートする必要があるか？
• オフラインでの進行状況をどのように扱うか？
• プレーヤーのローカル保存がクラウド内のデータと競合する場合、どのように対処するか？

ゲームへの署名とパッケージング

• 実行可能コードが、実際にそれを作成した者によるものであること、および、コードが改ざんされていないことを保証するために、Apple はコード署名という手段を取っています。詳細はこちらでご覧になれます。
• 資格 (Entitlements) は、コード署名を行っている間にアプリに埋め込まれるキーと値のペアです。iCloud など、アプリが利用できる特定の安全な OS の機能を意味しています。詳細はこちらをご覧ください。
• Information Property List (情報プロパティ リスト ファイル) または Info.plist には、アプリケーションと App Store のための重要なコンフィギュレーション データが格納されています。たとえば、アプリのアイコンの場所やサポートされている言語などが含まれています。詳細はこちらをご覧ください。

ローカルで開発するためのパッケージングと署名

<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE plist PUBLIC "-//Apple//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
<plist version="1.0">
<dict>
    <key>com.apple.application-identifier</key>
    <string>TEAMID.com.mycompany.mygame</string>
    <key>com.apple.developer.icloud-container-environment</key>
    <string>Development</string>
    <key>com.apple.developer.icloud-services</key>
    <array>
        <string>CloudKit</string>
    </array>
    <key>com.apple.developer.icloud-container-identifiers</key>
    <array>
        <string>iCloud.com.mycompany.mygame</string>
    </array>
    <key>com.apple.developer.game-center</key>
    <true/>
    <key>com.apple.security.app-sandbox</key>
    <true/>
</dict>
</plist>

• com.apple.application-identifier が完全なアプリ Bundle ID である (重要：Bundle ID は、チーム ID から始まるようにします。「3Y1CL48M1K」のように、文字列と数字から成り立っている必要があります)。
• com.apple.developer.icloud-container-identifiers の配列を変更して、iCloud コンテナ ID が含まれるようにします。

codesign --deep -f -v -s "3rd Party Mac Developer:" --entitlements entitlements.plist MyGame.app

配布のためのパッケージングと署名

lipo MyGame.app/Contents/UE4/Engine/Binaries/ThirdParty/Ogg/Mac/libogg.dylib -remove i386 -output MyGame.app/Contents/UE4/Engine/Binaries/ThirdParty/Ogg/Mac/libogg.dylib

lipo MyGame.app/Contents/UE4/Engine/Binaries/ThirdParty/Vorbis/Mac/libvorbis.dylib -remove i386 -output MyGame.app/Contents/UE4/Engine/Binaries/ThirdParty/Vorbis/Mac/libvorbis.dylib

lipo MyGame.app/Contents/UE4/Engine/Binaries/ThirdParty/OpenVR/OpenVRv1_0_16/osx32/libopenvr_api.dylib -remove i386 -output MyGame.app/Contents/UE4/Engine/Binaries/ThirdParty/OpenVR/OpenVRv1_0_16/osx32/libopenvr_api.dylib

rm -rf MyGame.app/Contents/Resources/RadioEffectUnit.component
rm -rf MyGame.app/Contents/UE4/Engine/Build

<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE plist PUBLIC "-//Apple//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
<plist version="1.0">
<dict>
    <key>com.apple.application-identifier</key>
    <string>TEAMID.com.mycompany.mygame</string>
    <key>com.apple.developer.icloud-container-environment</key>
    <string>Production</string>
    <key>com.apple.developer.icloud-services</key>
    <array>
        <string>CloudKit</string>
    </array>
    <key>com.apple.developer.icloud-container-identifiers</key>
    <array>
        <string>iCloud.com.mycompany.mygame</string>
    </array>
    <key>com.apple.developer.game-center</key>
    <true/>
    <key>com.apple.security.app-sandbox</key>
    <true/>
</dict>
</plist>

• com.apple.application-identifier が完全なアプリ Bundle ID である (重要：Bundle ID は、チーム ID から始まるようにします。「3Y1CL48M1K」のように、文字列と数字から成り立っている必要があります)。
• com.apple.developer.icloud-container-identifiers を変更して、iCloud コンテナ ID が含まれるようにします。

codesign -f -v -s "3rd Party Mac Developer Application:" --entitlements entitlements.plist MyGame.app/Contents/MacOS/MyGame

find MyGame.app/Contents/ | grep .dylib | xargs codesign -f -v -s "3rd Party Mac Developer Application:" --entitlements entitlements.plist

codesign -f -v -s "3rd Party Mac Developer Application:" --entitlements entitlements.plist MyGame.app/

productbuild --component MyGame.app/ /Applications --sign "3rd Party Mac Developer Installer:" MyGame.pkg

よくあるパッケージングの問題