Apple Mac 환경에 언리얼 엔진 연동하기

• Mac App Store에서 게임을 출시하면, 게임 위주의 디지털 스토어를 사용하지 않는 플레이어에게도 게임이 자연스럽게 노출됩니다.
• iCloud 또는 Game Center를 사용하여 리더보드와 클라우드 저장을 처리하면, 앱에 서드파티 프레임워크를 도입하지 않아도 믿을 수 있는 퍼스트파티 서비스를 무료로 이용할 수 있습니다.
• Apple Arcade는 다양한 기기에 걸쳐 클라우드 저장 기능을 제공하기 위해 Game Center와 iCloud가 필요합니다.

Apple Developer 포털에서 Mac 앱 설정

1. Apple Developer Program에 가입합니다(1년에 $99 USD).
2. 인증서, 식별자 및 프로필 페이지의 식별자 항목을 통해 앱을 생성합니다.
   1. 앱에 'com.mycompany.mygame'과 같은 유용한 번들 ID를 부여합니다.
   2. iCloud와 Game Center 기능을 활성화하고, 따로 원하는 기능이 있으면 활성화합니다.
   3. 참고: 이미 게임의 iOS 버전용 앱 식별자가 있는 경우, iOS 앱 식별자 설정에서 'Mac' 기능을 선택하여 Mac 식별자를 자동 생성할 수 있습니다.
3. 인증서, 식별자 및 프로파일 페이지의 인증서 항목을 통해 계정의 인증서를 생성합니다.
   1. 로컬에서 인증서 서명 요청을 생성합니다.
   2. 이를 통해 다음 용도의 인증서를 생성, 다운로드합니다.
      1. Mac 개발
      2. Mac 앱 배포
      3. Mac 인스톨러 배포
4. 인증서, 식별자 및 프로파일 페이지의 기기 항목을 통해 테스트 또는 개발용 Mac을 추가합니다.
   1. 시스템 보고 기능을 통해 Mac UDID를 확인할 수 있습니다.
5. (선택사항) 인증서, 식별자 및 프로필 페이지의 식별자 항목을 통해 iCloud 저장소를 생성합니다.
   1. 앱 식별자를 편집하고, iCloud 기능 옆에 있는 버튼으로 저장소를 배정합니다.
6. 관련 프로비저닝 프로파일을 생성 및 다운로드합니다.
   1. Mac 개발 프로비저닝 프로필을 생성합니다.
      1. 반드시 새로 생성한 앱 식별자, 인증서, 기기를 선택합니다.
   2. Mac App Store 프로비저닝 프로필을 생성합니다.
7. App Store Connect에서 새로운 macOS 앱을 생성하고, 새로운 번들 식별자를 선택합니다.
8. 언리얼에서 프로젝트를 엽니다. 프로젝트 설정에서 플랫폼 > iOS로 이동한 다음, 번들 식별자를 새로운 번들 ID로 설정합니다.

Mac 게임과 Apple API 연동

Objective-C++란?

Mac에서 Game Center 지원

1. 플레이어 인증
2. 인증된 플레이어를 사용하여 업적, 리더보드 등을 호출합니다.

 if (Target.Platform == UnrealTargetPlatform.Mac) {
            PublicFrameworks.AddRange(new string[]{"GameKit"});
        }

#include <GameKit/GameKit.h>

void UMyBlueprintFunctionLibrary::GameCenterSignIn() {
#if WITH_EDITOR
    // 에디터에서 실행하지 않음
#elif PLATFORM_MAC
    // GameCenter에 비동기로 로그인. 코드에 다음 사항을 추가하는 것을 추천합니다
    // 로그인이 오래 걸리는 경우를 제어할 수 있도록
    // 델리게이트 또는 UBlueprintAsyncActionBase 포함.
    dispatch_async(dispatch_get_main_queue(), ^{
        [[GKLocalPlayer localPlayer]
         setAuthenticateHandler:^(NSViewController *_Nonnull viewController, NSError *error) {
             if ([[GKLocalPlayer localPlayer] isAuthenticated])
             {
                 // 성공
                 return;
             }
             if (error)
             {
                 // 실패
             }
             else if (viewController)
             {
                 // 디스플레이 로그인
                 GKDialogController *presenter = [GKDialogController sharedDialogController];
                 presenter.parentWindow = [NSApp keyWindow];
                 [presenter presentViewController:(NSViewController * _Nonnull) viewController];
             }
         }];
    });
#endif
}

#include <GameKit/GameKit.h>

void UMyBlueprintFunctionLibrary::WriteAchievement(FString ID, float Percent)
{
#if PLATFORM_MAC
    if (![[GKLocalPlayer localPlayer] isAuthenticated])
        return;
    
    // FString을 NSString으로 전환
    NSString *nsID = [NSString stringWithUTF8String:TCHAR_TO_ANSI(*ID)];
    
    GKAchievement *achievement = [[GKAchievement alloc] initWithIdentifier:nsID];
    achievement.percentComplete = Percent;
    achievement.showsCompletionBanner = YES;
    [GKAchievement reportAchievements:@[ achievement ]withCompletionHandler:^(NSError *error) {
        if (error != nil)
        {
            NSLog(@"%@", [error localizedDescription]);
        }
    }];
#endif
}

#include <GameKit/GameKit.h>

void UMyBlueprintFunctionLibrary::WriteScoreToLeaderboard(FString LeaderboardID, int Integer) {
#if PLATFORM_MAC
    if (![[GKLocalPlayer localPlayer] isAuthenticated])
        return;
    
    // FString을 NSString으로 전환
    NSString *nsID = [NSString stringWithUTF8String:TCHAR_TO_ANSI(*LeaderboardID)];
    
    GKScore *score = [[GKScore alloc] initWithLeaderboardIdentifier:nsID];
    score.value = Integer;
    
    [GKScore reportScores:@[score] withCompletionHandler:^(NSError *error) {
        if (error != nil)
        {
            NSLog(@"%@", [error localizedDescription]);
        }
    }];
#endif
}

클라우드 저장에 iCloud 사용

1. iCloud에서는 저장 오브젝트의 각 항목을 고유 항목으로 다루어야 합니다. 예를 들어 플레이어의 레벨 항목은 ‘Level’이라는 Integer, 캐릭터 이름은 ‘Name’이라는 String이 되어야 합니다.
2. 저장 오브젝트를 바이너리 데이터로 직렬화하고, 저장 정보 전체를 단일 iCloud 항목에 하나의 바이너리 글로브로 업로드합니다.

if (Target.Platform == UnrealTargetPlatform.Mac) {
            PublicWeakFrameworks.Add("CloudKit");
        }

#include <CloudKit/CloudKit.h>
#include "GameFramework/SaveGame.h"
#include "Kismet/GameplayStatics.h"
#include "Serialization/MemoryReader.h"
#include "Serialization/MemoryWriter.h"
#include "Serialization/ObjectAndNameAsStringProxyArchive.h"


void UMyBlueprintFunctionLibrary::WriteSaveToCloud(USaveGame* MySave) {
    TArray<uint8> ObjectBytes;
    FMemoryWriter MemoryWriter(ObjectBytes, true);
    FObjectAndNameAsStringProxyArchive Ar(MemoryWriter, false);
    MySave->Serialize(Ar);
    
    CKContainer *defaultContainer =
        [CKContainer containerWithIdentifier:@"iCloud.unrealtutorial.mygame"];
    if (defaultContainer == nil)
    {
        // 초기화 실패
        return;
    }
    else
    {
        CKDatabase *DB = [defaultContainer privateCloudDatabase];
        CKRecordID *recordId = [[[CKRecordID alloc] initWithRecordName:@"save_game_id"] autorelease];
        // Apple 온라인 대시보드에서 RecordType "SaveGame" 설정 완료
        CKRecord *record = [[CKRecord alloc] initWithRecordType:@"SaveGame" recordID:recordId];
        // 언리얼 데이터 배열을 NSData 바이트로 전환 
        NSData *data = [NSData dataWithBytes:ObjectBytes.GetData() length:ObjectBytes.Num()];
        record[@"SaveData"] = data;
        
        // CKModifyRecordsOperation을 사용하여 기존 기록 업데이트 
        CKModifyRecordsOperation *modifyRecords =
        [[CKModifyRecordsOperation alloc] initWithRecordsToSave:@[ record ]
                                              recordIDsToDelete:nil];
        modifyRecords.savePolicy = CKRecordSaveAllKeys;
        modifyRecords.qualityOfService = NSQualityOfServiceUserInitiated;
        modifyRecords.perRecordCompletionBlock = ^(CKRecord *results, NSError *error) {
            if (error != nil)
            {
                NSLog(@"icloud save error: %@", error);
            }
            else
            {
                NSLog(@"icloud save success: %@", results);
            }
        };
        [DB addOperation:modifyRecords];
    }
}

#include 
#include "GameFramework/SaveGame.h"
#include "Kismet/GameplayStatics.h"
#include "Serialization/MemoryReader.h"
#include "Serialization/MemoryWriter.h"
#include "Serialization/ObjectAndNameAsStringProxyArchive.h"

UCustomSaveGame* UMyBlueprintFunctionLibrary::LoadFromCloud() {
    CKContainer *defaultContainer =
    [CKContainer containerWithIdentifier:@"iCloud.unrealtutorial.mygame"];
    if (defaultContainer == nil)
    {
        return nullptr;
    }
    else
    {
        NSPredicate *predicate = [NSPredicate predicateWithFormat:@"TRUEPREDICATE"];
        CKDatabase *publicDatabase = [defaultContainer privateCloudDatabase];
        CKRecordID *recordID = [[CKRecordID alloc] initWithRecordName:@"save_game_id"];
        
        __block NSData *data = nil;
        // 이 블록의 결과값을 계속 유지하여 데이터가 GC되지 않도록 합니다.
        __block CKRecord *holdResults;
        
        // 참고: 델리게이트, 세마포어 또는 다른 바으로 동기화되어야 합니다
        [publicDatabase
         fetchRecordWithID:recordID
         completionHandler:^(CKRecord *results, NSError *error) {
             holdResults = results;
             if (error != nil)
             {
                 NSLog(@"icloud load error: %@", error);
             }
             else
             {
                 NSLog(@"icloud load success: %@", results);
                 data = [[NSData alloc] initWithData:(NSData *) results[@"SaveData"]];
             }
         }];
        
        // Sleep으로 동기화하지 마시오 -- 예시에만 해당합니다
        usleep(3000000); // 비동기 로드 대기
                
        // 저장된 오브젝트로 데이터를 읽어들입니다
        TArray ObjectBytes;
        ObjectBytes.AddUninitialized(data.length);
        FMemory::Memcpy(ObjectBytes.GetData(), data.bytes, data.length * sizeof(uint8));
        FMemoryReader MemoryReader(ObjectBytes, true);
        FObjectAndNameAsStringProxyArchive Ar(MemoryReader, true);
        UCustomSaveGame *LoadedSave = Cast(                                                                UGameplayStatics::CreateSaveGameObject(UCustomSaveGame::StaticClass()));

        LoadedSave->Serialize(Ar);
        return LoadedSave;
    }
}

• 게임이 얼마나 자주 저장됩니까? 얼마나 자주 불러옵니까? 저장하고 불러올 때마다 클라우드와 소통해야 합니까, 아니면 일부만 그렇습니까?
• 동일한 iCloud 기록을 읽고 쓰기 위해서 여러 기기를 지원해야 합니까?
• 오프라인 진행률은 어떻게 처리합니까?
• 플레이어의 로컬 저장 데이터와 클라우드 데이터가 충돌하면 게임에서 어떻게 처리합니까?

코드 서명 및 패키징

• 코드 서명은 Apple이 실행 가능한 코드의 실제작자를 확인하고, 코드가 조작되지 않았음을 보장하기 위해 사용하는 수단입니다. 자세한 내용은 여기서 확인하세요.
• 자격은 앱이 활용할 수 있는 iCloud 등 안전한 OS 기능 이용을 위해 코드 서명 시 앱에 키값 쌍을 넣는 것입니다. 자세한 내용은 여기서 확인하세요.
• 정보 프로퍼티 리스트(Information Property List) 또는 ‘Info.plist’는 App Icon 위치 또는 지원 언어 등 애플리케이션과 App Store의 핵심 설정 데이터를 포함합니다. 자세한 내용은 여기서 확인하세요.

로컬 개발 패키징 및 서명

<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE plist PUBLIC "-//Apple//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
<plist version="1.0">
<dict>
    <key>com.apple.application-identifier</key>
    <string>TEAMID.com.mycompany.mygame</string>
    <key>com.apple.developer.icloud-container-environment</key>
    <string>Development</string>
    <key>com.apple.developer.icloud-services</key>
    <array>
        <string>CloudKit</string>
    </array>
    <key>com.apple.developer.icloud-container-identifiers</key>
    <array>
        <string>iCloud.com.mycompany.mygame</string>
    </array>
    <key>com.apple.developer.game-center</key>
    <true/>
    <key>com.apple.security.app-sandbox</key>
    <true/>
</dict>
</plist>

• com.apple.application-identifier는 전체 앱 번들의 식별자입니다. (중요: 번들 식별자는 team ID로 시작해야 합니다. Team ID는 ‘3Y1CL48M1K’와 같이 문자와 숫자로 이루어진 String입니다)
• com.apple.developer.icloud-container-identifiers 배열에 iCloud 저장소 ID를 추가합니다.

codesign --deep -f -v -s "3rd Party Mac Developer:" --entitlements entitlements.plist MyGame.app

배포를 위한 패키징 및 서명

lipo MyGame.app/Contents/UE4/Engine/Binaries/ThirdParty/Ogg/Mac/libogg.dylib -remove i386 -output MyGame.app/Contents/UE4/Engine/Binaries/ThirdParty/Ogg/Mac/libogg.dylib

lipo MyGame.app/Contents/UE4/Engine/Binaries/ThirdParty/Vorbis/Mac/libvorbis.dylib -remove i386 -output MyGame.app/Contents/UE4/Engine/Binaries/ThirdParty/Vorbis/Mac/libvorbis.dylib

lipo MyGame.app/Contents/UE4/Engine/Binaries/ThirdParty/OpenVR/OpenVRv1_0_16/osx32/libopenvr_api.dylib -remove i386 -output MyGame.app/Contents/UE4/Engine/Binaries/ThirdParty/OpenVR/OpenVRv1_0_16/osx32/libopenvr_api.dylib

rm -rf MyGame.app/Contents/Resources/RadioEffectUnit.component
rm -rf MyGame.app/Contents/UE4/Engine/Build

<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE plist PUBLIC "-//Apple//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
<plist version="1.0">
<dict>
    <key>com.apple.application-identifier</key>
    <string>TEAMID.com.mycompany.mygame</string>
    <key>com.apple.developer.icloud-container-environment</key>
    <string>Production</string>
    <key>com.apple.developer.icloud-services</key>
    <array>
        <string>CloudKit</string>
    </array>
    <key>com.apple.developer.icloud-container-identifiers</key>
    <array>
        <string>iCloud.com.mycompany.mygame</string>
    </array>
    <key>com.apple.developer.game-center</key>
    <true/>
    <key>com.apple.security.app-sandbox</key>
    <true/>
</dict>
</plist>

• com.apple.application-identifier는 전체 앱 번들의 식별자입니다. (중요: 번들 식별자는 team ID로 시작해야 합니다. Team ID는 '3Y1CL48M1K'와 같이 문자와 숫자로 이루어진 String입니다)
• com.apple.developer.icloud-container-identifiers에 iCloud 저장소 ID를 추가합니다.

codesign -f -v -s "3rd Party Mac Developer Application:" --entitlements entitlements.plist MyGame.app/Contents/MacOS/MyGame

find MyGame.app/Contents/ | grep .dylib | xargs codesign -f -v -s "3rd Party Mac Developer Application:" --entitlements entitlements.plist

codesign -f -v -s "3rd Party Mac Developer Application:" --entitlements entitlements.plist MyGame.app/

productbuild --component MyGame.app/ /Applications --sign "3rd Party Mac Developer Installer:" MyGame.pkg

일반적인 패키징 문제